
OPEN WINDOW 640,512
SETRGB 0,32,0,0
CLEAR WINDOW

DIM BOARD(10,10)
DIM C1(16):DIM C2(16)
DIM CPU(4):DIM CLR(4,3)
DIM XP(8):DIM YP(8)
DIM YM(8):DIM CDOWN$(3)
DIM GP(8):DIM SP(8)
DIM X(8):DIM Y(8):DIM Z(8)
DIM PX(8):DIM PY(8):DIM PZ(8)
DIM F1(6):DIM F2(6)
DIM F3(6):DIM F4(6)
DIM R(6):DIM G(6):DIM B(6)
DIM SN(360):DIM CS(360)
DIM RNDXR(6):DIM RNDYR(6)
DIM WIN(6)

RESTORE PCOLOUR
FOR P=0 TO 3
FOR C=0 TO 2
READ CLR(P,C)
NEXT C
NEXT P
RESTORE TTO
FOR A=0 TO 3
READ CDOWN$(A)
NEXT A
FOR A=0 TO 359
SN(A)=SIN(A*PI/180):CS(A)=COS(A*PI/180)
NEXT A
RESTORE CUBEDATA
FOR A=0 TO 7
READ X(A),Y(A),Z(A)
NEXT A
FOR A=0 TO 5
READ F1(A),F2(A),F3(A),F4(A),R(A),G(A),B(A)
NEXT A
FOR RND=0 TO 5
READ RNDXR(RND),RNDYR(RND)
NEXT RND

1 RESTORE TS
SETRGB 1,128,128,128
FOR X=0 TO 22
FOR Y=0 TO 6
RECT 80+X*20,20+Y*20 TO 100+X*20,40+Y*20
NEXT Y
NEXT X
FOR A=0 TO 66
READ TSX,TSY
P=INT(TSX/6)
SETRGB 1,CLR(P,0),CLR(P,1),CLR(P,2)
FILL RECT 81+TSX*20,21+TSY*20 TO 99+TSX*20,39+TSY*20
WAIT 0.1
NEXT A
SETRGB 1,200,200,200
TEXT 280,200,"WARFARE"
TEXT 50,400,"PRESS START TO PLAY"
R=200:G=0:B=0:STOP=0
REPEAT
IF R=200 AND G<200 AND B=0 G=G+4
IF R>0 AND G=200 AND B=0 R=R-4
IF R=0 AND G=200 AND B<200 B=B+4
IF R=0 AND G>0 AND B=200 G=G-4
IF R<200 AND G=0 AND B=200 R=R+4
IF R=200 AND G=0 AND B>0 B=B-4
SETRGB 1,R,G,B
FILL RECT 0,280 TO 640,305
SETRGB 1,0,0,0
TEXT 150,300,"BY NORTHERN LIGHTS PARTY PLAY 2002"
BA=PEEK("port1")
BB=PEEK("port2")
IF AND(BA,8)=8 OR AND(BB,8)=8 STOP=1
WAIT 0.03
UNTIL(STOP=1)

10 CLEAR WINDOW
SETRGB 1,128,128,128
GOSUB 904
RESTORE GWARINST
GOSUB 908
SETRGB 1,128,128,128
TEXT 70,65,"TO VIEW AN ONLINE INSTRUCTION MANUAL PRESS START NOW"
RECT 90,90 TO 500,210
YM(0)=155
TEXT 110,110,"WHO IS PLAYING?"
TEXT 110,125,"L2 - START GAME"
FOR P=0 TO 3
SETRGB 1,CLR(P,0),CLR(P,1),CLR(P,2)
TEXT 110+P*100,155,"MAN "+STR$(P+1)+"UP"
TEXT 110+P*100,170,"NO PLAY"
NEXT P
SETRGB 1,128,128,128
R=0:PL=3:LM=2
REPEAT
GOSUB 901
IF C1(8)=0 AND R=2 AND M>1 R=1
IF R=2 AND M<2 R=0
M=0
FOR P=0 TO 3
CPU(P)=(YM(P)-155)/15
IF CPU(P)=0 M=M+1
SP(P)=0
NEXT P
IF C1(3)=1 INST=1
IF INST=1 AND C1(3)=0 GOTO 1234
UNTIL(R=1)
GOTO 3
GOSUB 902
CLEAR WINDOW
IF M=2 BD=6:IF M=3 BD=8:IF M=4 BD=9
XGR=320-(BD+1)*15:XGE=XGR+30
YGR=256-(BD+1)*15:YGE=YGR+30
SIZE=(BD+1)*1.5
FOR L=3 TO 0 STEP -1
IF CPU(L)=0 LSC=L
NEXT L
FOR ROUND=0 TO 5
SPACE=(BD+1)^2-M:P=LSC:PL=M

REPEAT
SETDRAWBUF DW
DW=1-DW
SETDISPBUF DW
CLEAR WINDOW
FOR A=0 TO 7
X1=X(A):Y1=Y(A):Z1=Z(A)
XX=X1
YY=Y1*CS(XR)+Z1*SN(XR)
ZZ=Z1*CS(XR)-Y1*SN(XR)
X1=XX*CS(YR)-ZZ*SN(YR)
Y1=YY
Z1=XX*SN(YR)+ZZ*CS(YR)
DV=(Z1/40)+1
X1=SIZE*(X1/DV)+320
Y1=SIZE*(Y1/DV)+256
PX(A)=X1
PY(A)=Y1
PZ(A)=Z1
NEXT A
XR=XR+SIG(XAD):YR=YR+SIG(YAD)
IF XR>359 XR=XR-360:IF YR>359 YR=YR-360
FOR A=0 TO 5
VX1=PX(F1(A))-PX(F2(A))
VY1=PY(F1(A))-PY(F2(A))
VX2=PX(F3(A))-PX(F2(A))
VY2=PY(F3(A))-PY(F2(A))
N=VX1*VY2-VX2*VY1
IF N<0 THEN
N=-(N/2000)
SETRGB 1,R(A)+N,G(A)+N,B(A)+N
FILL TRIANGLE PX(F1(A)),PY(F1(A)) TO PX(F2(A)),PY(F2(A)) TO PX(F3(A)),PY(F3(A))
FILL TRIANGLE PX(F1(A)),PY(F1(A)) TO PX(F4(A)),PY(F4(A)) TO PX(F3(A)),PY(F3(A))
FI
NEXT A
XAD=ABS(XR-RNDXR(ROUND)):YAD=ABS(YR-RNDYR(ROUND))
UNTIL(XAD=0 AND YAD=0)
WAIT 1
SETDRAWBUF 0
SETDISPBUF 0
3 CLEAR WINDOW
SETRGB 1,128,128,128
FOR A=0 TO BD
FOR B=0 TO BD
BOARD(A,B)=4
RECT XGR+A*30,YGR+B*30 TO XGE+A*30,YGE+B*30
NEXT B
NEXT A
FOR PP=0 TO 3
2 START=INT(RAN(4))
XP(PP)=BD*AND(START,1)
YP(PP)=BD*AND(START,2)/2
FOR Q=0 TO PP
IF PP<>Q AND XP(PP)=XP(Q) AND YP(PP)=YP(Q) GOTO 2
NEXT Q
SETRGB 1,CLR(PP,0),CLR(PP,1),CLR(PP,2)
IF CPU(PP)=0 THEN
BOARD(XP(PP),YP(PP))=PP:GP(PP)=1
FILL RECT XGR+3+XP(PP)*30,YGR+3+YP(PP)*30 TO XGE-3+XP(PP)*30,YGE-3+YP(PP)*30
FI
FILL RECT 20+PP*150,15 TO 170+PP*150,30
SETRGB 1,128,128,128
TEXT 50+PP*150,45,STR$(GP(PP))+" GERMS"
TEXT 50+PP*150,60,STR$(SP(PP))+" POINTS"
NEXT PP
REPEAT
BA=PEEK("port1")
BB=PEEK("port2")
FOR A=0 TO 15
C1(A)=SIG(AND(BA,2^A))
C2(A)=SIG(AND(BB,2^A))
NEXT A
SETRGB 1,128,128,128
MOVE=0
FOR X=0 TO BD
FOR Y=0 TO BD
IF BOARD(X,Y)=P THEN
XMN=MAX(0,X-2):YMN=MAX(0,Y-2)
XMX=MIN(BD,X+2):YMX=MIN(BD,Y+2)
FOR XX=XMN TO XMX
FOR YY=YMN TO YMX
IF BOARD(XX,YY)=4 MOVE=MOVE+1
NEXT YY
NEXT XX
FI
NEXT Y
NEXT X
CLEAR FILL RECT 20,93 TO 640,77
IF CPU(P)=0 AND GP(P)>0 THEN
TEXT 20,90,"PLAYER "+STR$(P+1)+" HAS " +STR$(MOVE)+" AVAILABLE MOVES"
ELSE
IF CPU(P)=0 TEXT 20,90,"PLAYER "+STR$(P+1)+" IS EXTINCT"
FI
IF MOVE=0 OR GP(P)=0 WAIT 2
IF CPU(P)=0 AND MOVE>0 AND GP(P)>0 THEN
CLEAR RECT XGR+1+XP(P)*30,YGR+1+YP(P)*30 TO XGE-1+XP(P)*30,YGE-1+YP(P)*30
SETRGB 1,CLR(P,0),CLR(P,1),CLR(P,2)
FILL TRIANGLE 20+P*150,75 TO 170+P*150,75 TO 95+P*150,60
IF P=0 THEN
XP(P)=XP(P)+C1(5)-C1(7):YP(P)=YP(P)+C1(6)-C1(4)
B1=C1(10):B2=C1(8)
FI
IF P=1 THEN
XP(P)=XP(P)+C2(5)-C2(7):YP(P)=YP(P)+C2(6)-C2(4)
B1=C2(10):B2=C2(8)
FI
IF P=2 THEN
XP(P)=XP(P)+C1(13)-C1(15):YP(P)=YP(P)+C1(14)-C1(12)
B1=C1(11):B2=C1(9)
FI
IF P=3 THEN
XP(P)=XP(P)+C2(13)-C2(15):YP(P)=YP(P)+C2(14)-C2(12)
B1=C2(11):B2=C2(9)
FI
XP(P)=MIN(XP(P),BD):XP(P)=MAX(XP(P),0)
YP(P)=MIN(YP(P),BD):YP(P)=MAX(YP(P),0)
RECT XGR+1+XP(P)*30,YGR+1+YP(P)*30 TO XGE-1+XP(P)*30,YGE-1+YP(P)*30
IF BOARD(XP(P),YP(P))=P AND MODE=0 AND B2=1 THEN
MODE=1
XP(P+4)=XP(P):YP(P+4)=YP(P)
FI
IF B1=1 MODE=0
XDIF=ABS(XP(P)-XP(P+4)):YDIF=ABS(YP(P)-YP(P+4))
IF MODE=1 AND (XDIF>0 OR YDIF>0) AND B2=1 THEN
IF XDIF>2 OR YDIF>2 OR BOARD(XP(P),YP(P))<4 MODE=0
IF MODE=1 THEN
IF XDIF=2 OR YDIF=2 THEN
BOARD(XP(P+4),YP(P+4))=4
CLEAR FILL RECT XGR+3+XP(P+4)*30,YGR+3+YP(P+4)*30 TO XGE-3+XP(P+4)*30,YGE-3+YP(P+4)*30
ELSE
SPACE=SPACE-1:GP(P)=GP(P)+1
FI
BOARD(XP(P),YP(P))=P
FILL RECT XGR+3+XP(P)*30,YGR+3+YP(P)*30 TO XGE-3+XP(P)*30,YGE-3+YP(P)*30
XMN=MAX(0,XP(P)-1):YMN=MAX(0,YP(P)-1)
XMX=MIN(BD,XP(P)+1):YMX=MIN(BD,YP(P)+1)
SCADD=0
FOR X=XMN TO XMX
FOR Y=YMN TO YMX
IF BOARD(X,Y)<4 AND BOARD(X,Y)<>P THEN
Q=BOARD(X,Y)
GP(Q)=GP(Q)-1
CLEAR FILL RECT 50+Q*150,48 TO 140+Q*150,31
SETRGB 1,128,128,128
TEXT 50+Q*150,45,STR$(GP(Q))+" GERMS"
IF GP(Q)=0 THEN
PL=PL-1
FOR PP=0 TO 3
IF CPU(PP)=0 SP(PP)=SP(PP)+GP(PP)
NEXT PP
FI
BOARD(X,Y)=P:GP(P)=GP(P)+1:SCADD=SCADD+1
SETRGB 1,CLR(P,0),CLR(P,1),CLR(P,2)
FILL RECT XGR+3+X*30,YGR+3+Y*30 TO XGE-3+X*30,YGE-3+Y*30
FI
WAIT 0.5
NEXT Y
NEXT X
SP(P)=SP(P)+INT(2^(SCADD-1))
CLEAR FILL RECT 50+P*150,63 TO 140+P*150,31
SETRGB 1,128,128,128
TEXT 50+P*150,45,STR$(GP(P))+" GERMS"
TEXT 50+P*150,60,STR$(SP(P))+" POINTS"
MODE=2
FI
FI
FI
IF MODE=2 OR CPU(P)=1 OR MOVE=0 THEN
CLEAR FILL TRIANGLE 20+P*150,75 TO 170+P*150,75 TO 95+P*150,60
P=P+1:MODE=0
FI
IF P=4 P=0
WAIT 0.1
UNTIL(SPACE=0 OR PL=1)
FOR P=0 TO 3
SP(P+4)=SP(P):GP(P+4)=GP(P)
NEXT P
WHILE(PL>1)
LOW=100
FOR P=0 TO 3
IF CPU(P)=0 AND GP(P)>0 THEN
LOW=MIN(GP(P),LOW)
FI
NEXT P
FOR P=0 TO 3
IF CPU(P)=0 THEN
IF GP(P)>0 GP(P)=GP(P)-LOW
IF GP(P)=0 PL=PL-1
SP(P)=SP(P)+GP(P)
FI
NEXT P
WEND
HIGH=0
FOR P=0 TO 3
HIGH=MAX(GP(P),HIGH)
IF GP(P)=HIGH THEN
WIN(ROUND)=P
FOR Q=0 TO P
IF Q<>P AND GP(P)=GP(Q) THEN
IF SP(P)<SP(Q) WIN(ROUND)=Q
FI
NEXT Q
FI
NEXT P
PP=WIN(ROUND)
R(ROUND)=CLR(PP,0)/4
G(ROUND)=CLR(PP,1)/4
B(ROUND)=CLR(PP,2)/4
LSC=4:LSCR=100000
FOR P=0 TO 3
IF SP(P)<LSCR AND CPU(P)=0 THEN
LSCR=SP(P):LSC=P
FI
NEXT P
WAIT 2
SETRGB 0,CLR(PP,0)/4,CLR(PP,1)/4,CLR(PP,2)/4
CLEAR WINDOW
SETRGB 1,0,0,0
TEXT 50,50,"PLAYER "+STR$(PP+1)+" WINS ROUND "+STR$(ROUND+1)
TEXT 50,75,"PLAYER "+STR$(LSC+1)+" HAD THE LOWEST SCORE IN THIS ROUND"
IF ROUND<5 TEXT 50,90,"AND WILL GO FIRST IN THE NEXT"
FOR P=0 TO 3
IF CPU(P)=0 THEN
TEXT 50,120+P*45,"PLAYER "+STR$(P+1)+" ENDED WITH "+STR$(GP(P+4))+" GERMS"
TEXT 50,135+P*45,"THEY SCORED "+STR$(SP(P)-SP(P+4))+" ROUND POINTS"
FI
NEXT P
TEXT 50,350,"PRESS START TO CONTINUE"
STOP=0
REPEAT
BA=PEEK("port1")
BB=PEEK("port2")
IF AND(BA,8)=8 OR AND(BB,8)=8 STOP=1
UNTIL(STOP=1)
SETRGB 0,32,0,0
NEXT ROUND
CLEAR WINDOW
FOR P=0 TO 3
GP(P)=0
NEXT P
FOR ROUND=0 TO 5
GP(WIN(ROUND))=GP(WIN(ROUND))+1
NEXT ROUND
WIN=0
FOR P=0 TO 3
WIN=MAX(GP(P),WIN)
IF GP(P)=WIN THEN
WIN=P
FOR Q=0 TO P
IF Q<>P AND GP(P)=GP(Q) THEN
IF SP(P)<SP(Q) WIN=Q
FI
NEXT Q
FI
NEXT P
SETRGB 1,0,0,0
SETRGB 0,CLR(WIN,0)/4,CLR(WIN,1)/4,CLR(WIN,2)/4
TEXT 50,50,"PLAYER "+STR$(WIN+1)+" WINS THE GAME!"
FOR P=0 TO 3
IF CPU(P)=0 THEN
TEXT 50,120+P*45,"PLAYER "+STR$(P+1)+" WON "+STR$(GP(P))+" ROUNDS"
TEXT 50,135+P*45,"THEY SCORED "+STR$(SP(P))+" POINTS"
FI
NEXT P
TEXT 50,350,"PRESS START TO CONTINUE"
STOP=0
REPEAT
BA=PEEK("port1")
BB=PEEK("port2")
IF AND(BA,8)=8 OR AND(BB,8)=8 STOP=1
UNTIL(STOP=1)
SETRGB 0,32,0,0
GOTO 1

1234 CLEAR WINDOW
INST=2:LM=0
SETRGB 1,255,128,0
TEXT 20,30,"TO EXIT THESE INSTRUCTIONS AT ANY STAGE PRESS START"
RESTORE ALLINST
1235 PAGE=PAGE+1:NXT=0
CLEAR FILL RECT 20,46 TO 640,512
TEXT 20,75,"L2 - NEXT"
TEXT 20,60,"PAGE "+STR$(PAGE)
GOSUB 906
REPEAT
GOSUB 901
IF C1(3)=1 INST=1
IF INST=1 AND C1(3)=0 INST=0
IF C1(8)=1 NXT=1
IF PAGE<7 AND NXT=1 AND C1(8)=0 GOTO 1235
UNTIL(INST=0)
PAGE=0:GOTO 10

901 BA=PEEK("port1")
BB=PEEK("port2")
FOR A=0 TO 15
C1(A)=SIG(AND(BA,2^A))
C2(A)=SIG(AND(BB,2^A))
NEXT A
WAIT 0.15
IF LM>0 THEN
IF C1(8)=1 R=2
IF C1(10)=1 R=4
IF C1(10)=0 AND R=4 R=3
FOR P=0 TO PL
YM(P+4)=YM(P)
IF P=0 YM(P)=YM(P)+(C1(6)-C1(4))*15
IF P=1 YM(P)=YM(P)+(C2(6)-C2(4))*15
IF P=2 YM(P)=YM(P)+(C1(14)-C1(12))*15
IF P=3 YM(P)=YM(P)+(C2(14)-C2(12))*15
IF YM(P)>140+LM*15 YM(P)=155
IF YM(P)<155 YM(P)=140+LM*15
CLEAR FILL RECT (P+1)*100,YM(P+4) TO (P+1)*100+5,YM(P+4)-10
FILL RECT (P+1)*100,YM(P) TO (P+1)*100+5,YM(P)-10
NEXT P
FI
RETURN
902 CLEAR WINDOW
RECT 300,230 TO 370,260
FOR A=0 TO 3
TEXT 310,250,CDOWN$(A)
WAIT 1
CLEAR FILL RECT 310,231 TO 369,259
NEXT A
CLEAR WINDOW
RETURN
904 SETRGB 1,128,128,128
FOR B=0 TO 1
RESTORE PAD
RECT 200,400-B*150 TO 400,450-B*150
FOR A=0 TO 1
READ XX:READ YY:READ CC
CLEAR FILL CIRCLE XX,YY-B*150,CC
CIRCLE XX,YY-B*150,CC
NEXT A
FOR A=0 TO 5
READ XX:READ YY:READ A$
TEXT XX,YY-B*150,A$
NEXT A
NEXT B
RETURN
906 A=-1
REPEAT
A=A+1
READ INST$
TEXT 20,90+A*15,INST$
UNTIL(INST$="" OR A=28)
RETURN
908 FOR P=0 TO 3
SETRGB 1,CLR(P,0),CLR(P,1),CLR(P,2)
FOR B=0 TO 6
READ A$
TEXT 20+SIG(AND(P,2))*480,250+AND(P,1)*150+B*15,A$
NEXT B
NEXT P
RETURN

LABEL PCOLOUR
DATA 255,0,0,128,128,255,255,255,0,0,255,0
LABEL PAD
DATA 200,425,50,400,425,50,195,400,"U",195,460,"D",165,430,"L     R",395,400,"T",395,460,"X",365,430,"S     O"
LABEL GWARINST
DATA "1UP","L2=DO","L1=UNDO","U =UP","L =LEFT","R =RIGHT","D =DOWN","2UP","L2=DO","L1=UNDO","U =UP","L =LEFT","R =RIGHT","D =DOWN","3UP","R2=DO","R1=UNDO","T =UP","S =LEFT","O =RIGHT","X =DOWN","4UP","R2=DO","R1=UNDO","T =UP","S =LEFT","O =RIGHT","X =DOWN"
LABEL ALLINST
DATA "THIS IS THE GERM WARFARE INSTRUCTION MANUAL."
DATA "GERM WARFARE IS A GAME PROGRAMMED FOR THE"
DATA "PLAYSTATION 2, DESIGNED TO RUN WITH THE USE OF THE"
DATA "SUPPLIED DEMO DISK AND A MEMORY CARD (8MB) (FOR"
DATA "PLAYSTATION 2). THIS GAME IS A SIMPLE VERSION OF"
DATA "CHESS, AND ALTHOUGH THE GRAPHICS ARELESS THAN THE"
DATA "PLAYSTATION 2 IS CAPABLE OF, WE HOPE YOU APPRECIATE"
DATA "THE GAME PLAY."
DATA ""
DATA "THE PLAYER SELECT MENU ALLOWS YOU TO CHOOSE WHO IS"
DATA "PLAYING. UP TO FOUR PEOPLE, SHARING TWO PADS CAN"
DATA "PLAY. MORE DETAILS ON THE NEXT PAGE. SIMPLY USE"
DATA "UP, DOWN, TRIANGLE, OR CROSS TO SELECT THE PLAYERS."
DATA "WHEN YOU ARE HAPPY WITH YOUR SELECTION, PRESS L2 ON"
DATA "PAD 1 TO PLAY THE GAME."
DATA ""
DATA "FOUR WAY PLAY"
DATA "TO GET FOUR PLAYERS ON EACH GAME WITHOUT A MULTI-"
DATA "TAP, THE JOY-PADS ARE SPLIT IN TWO. PLAYER ONE USES"
DATA "THE D-PAD AND L BUTTONS ON PAD 1. PLAYER TWO USES"
DATA "THE D-PAD AND L BUTTONS ON PAD 2. PLAYER THREE USES"
DATA "THE TSOX AND R BUTTONS ON PAD 1. PLAYER FOUR USES"
DATA "THE TSOX AND R BUTTONS ON PAD 2."
DATA "TSOX STANDS FOR TRIANGLE, SQUARE, CIRCLE, CROSS."
DATA "THE USE OF TSOX BUTTONS IS SUPPOSED TO BE LIKENED"
DATA "TO THE USE OF THE D-PAD."
DATA "TRIANGLE IS UP, SQUARE IS LEFT, CIRCLE IS RIGHT,"
DATA "AND CROSS IS DOWN."
DATA "IN THIS GAME, PLAYER ONE IS RED,"
DATA "PLAYER TWO IS BLUE,"
DATA "PLAYER THREE IS YELLOW,"
DATA "AND PLAYER FOUR IS GREEN"
DATA ""
DATA "GERM WARFARE"
DATA "THE AIM OF THIS GAME IS TO END UP OCCUPYING THE"
DATA "MAJORITY OF THE SURFACE OF THE CUBE, OR EVEN"
DATA "BETTER, TO WIPE OUT YOUR OPPONENTS ALL TOGETHER."
DATA "THE GAME IS PLAYED IN 6 ROUNDS (ONE FOR EACH SIDE"
DATA "OF THE CUBE)."
DATA "PICTURE A CHESS BOARD IF YOU WILL. IF THE PIECE WE"
DATA "USE IN THIS GAME WERE IN CHESS, THIS IS WHAT WOULD"
DATA "HAPPEN -"
DATA "1. THE PIECE MAY MOVE 1 SQUARE IN ANY DIRECTION"
DATA "TO A SPACE WHICH IS NOT OCCUPIED. THIS WILL CAUSE"
DATA "THE PIECE TO REPLICATE, BECOMING 2 SEPERATE PIECES."
DATA "ANY ENEMY PIECES ADJACENT TO THE LANDING SITE ARE"
DATA "INFECTED."
DATA "2. THE PIECE MAY MOVE 2 SQUARES IN ANY DIRECTION"
DATA "AS LONG AS THE LANDING SITE IS NOT OCCUPIED. THIS"
DATA "MOVE ALLOWS THE PIECE TO JUMP, BUT NOT TO REPLICATE."
DATA "AS BEFORE, ANY ENEMY PIECES ADJACENT TO THE LANDING"
DATA "SITE BECOME INFECTED"
DATA "FROM HERE ON IN, ALL PIECES ARE REFERRED TO AS GERMS."
DATA ""
DATA "MOVING"
DATA "USING YOUR DIRECTIONAL OR TSOX BUTTONS, HIGHLIGHT"
DATA "THE GERM YOU WANT TO MOVE. PRESS L2 OR R2 TO"
DATA "SELECT THE HIGHLIGHTED GERM."
DATA "TO DESELECT A SELECTED GERM, PRESS L1 OR R1."
DATA "NOW HIGHLIGHT A LANDING SITE BY USING YOUR"
DATA "DIRECTIONAL OR TSOX BUTTONS, AND PRESS L2 OR R2"
DATA "TO SEND THE GERM TO WHERE YOU WANT IT."
DATA "YOU MAY ONLY MOVE GERMS OF YOUR OWN COLOUR."
DATA "IF YOU TRY TO SELECT A LANDING SITE WHICH IS OUT"
DATA "OF RANGE OR OCCUPIED, YOU WILL NEED TO RE-SELECT"
DATA "THE GERM YOU WISH TO MOVE."
DATA ""
DATA "THE NEXT ROUND"
DATA "IN THE FIRST ROUND, PLAYER 1 (RED) ALWAYS STARTS."
DATA "AS A HANDICAP, THE PLAYER WITH THE LOWEST SCORE IN"
DATA "THE PREVIOUS ROUND STARTS THE NEXT ROUND."
DATA "IF TWO OR MORE PLAYERS END A ROUND WITH THE SAME"
DATA "NUMBER OF GERMS, THE HIGHEST SCORE WILL DETERMINE"
DATA "THE WINNER."
DATA "AFTER EACH ROUND, THE COLOUR OF THE FACE OF THE"
DATA "CUBE FOR THAT ROUND WILL CHANGE TO THAT OF THE"
DATA "WINNER."
DATA "LIKEWISE, IF TWO OR MORE PLAYERS HAVE WON THE SAME"
DATA "NUMBER OR ROUNDS, THE END OF GAME SCORES WILL"
DATA "DETERMINE THE WINNER."
DATA ""
DATA "CREDITS"
DATA "       RESEARCHER - ANTHONY BLACK"
DATA "      GAME DESIGN - ANTHONY BLACK"
DATA "       PROGRAMMER - ANTHONY BLACK"
DATA "         GRAPHICS - ANTHONY BLACK"
DATA "          TESTERS - KENNETH BLACK"
DATA "                  - MICHELLE KNIGHT"
DATA "                  - ALEX MCGUINNESS"
DATA "SPECIAL THANKS TO - SONY"
DATA "                  - WWW.YABASIC.CO.UK"
DATA ""
LABEL TTO
DATA "THREE","TWO","ONE","GO!"
LABEL CUBEDATA
DATA -10,10,10, 10,10,10, 10,-10,10, -10,-10,10
DATA -10,10,-10, 10,10,-10, 10,-10,-10, -10,-10,-10
DATA 0,1,2,3,64,64,64
DATA 4,7,6,5,64,64,64
DATA 7,3,2,6,64,64,64
DATA 1,5,6,2,64,64,64
DATA 7,4,0,3,64,64,64
DATA 4,5,1,0,64,64,64
DATA 0,180,0,0,270,0,0,270,0,90,90,0
LABEL TS
DATA 0,1,0,2,1,0,0,3,2,0,0,4,3,0,0,5,4,1,1,6
DATA 6,1,2,6,6,2,3,6,6,0,3,5,6,3,3,4,7,0,2,4
DATA 6,4,4,4,7,3,8,0,6,5,8,3,9,0,6,6,10,0,12,0
DATA 7,6,12,1,8,6,13,0,9,6,12,2,10,6,14,0,12,3,15,0
DATA 12,4,16,1,13,3,12,5,16,2,14,3,12,6,15,3,14,4,15,5
DATA 16,6,18,6,18,5,18,4,18,3,18,2,18,1,19,0,20,1,21,0
DATA 20,2,22,1,22,2,22,3,22,4,22,5,22,6


